package {
	import away3d.cameras.Camera3D;
	import away3d.cameras.lenses.PerspectiveLens;
	import away3d.containers.View3D;
	import away3d.lights.PointLight;
	import away3d.textures.BitmapTexture;
 
	import flash.display.BitmapData;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.geom.Matrix;
	import flash.media.Camera;
	import flash.media.Video;
 
	[SWF(frameRate="60", width="640", height="480", backgroundColor="#DDDDDD")]
	public class Stage3DWebcam extends Sprite {
		private var _view : View3D;
		private var _camera : Camera3D;
		private var _light : PointLight;
		private var _cam : Camera;
		private var _vid : Video;
		private var _bmd : BitmapData;
		private var _matrix : Matrix;
 
		public function Stage3DWebcam() {
			init();
		}
 
		private function init() : void {
			_matrix = new Matrix(-1, 0, 0, 1, 320, 0);
 
			var view3D : View3D = new View3D();
			_view = view3D;
			view3D.backgroundColor = 0xefefef;
			view3D.antiAlias = 4;
			view3D.width = 640;
			view3D.height = 480;
 
			// Camera
			var camera : Camera3D = _camera = view3D.camera;
			camera.lens = new PerspectiveLens();
			camera.lens.far = 100000;
 
			// Light
			var pointLight : PointLight = new PointLight();
			_light = pointLight;
			pointLight.z = -300;
			pointLight.color = 0xffffff;
			pointLight.specular = 0.15;
 
			view3D.scene.addChild(pointLight);
			addChildAt(view3D, 0);
 
			_cam = Camera.getCamera();
			var cam : Camera = _cam;
 
			if (!cam) {
				throw new Error("No camera!");
				return;
			} else {
				setupCamera(cam);
				addEventListener(Event.ENTER_FRAME, onLoop);
			}
		}
 
		private function setupCamera(cam : Camera) : void {
			cam.setMode(320, 240, 30);
 
			var video : Video = new Video();
			_vid = video;
			video.width = 320;
			video.height = 240;
			video.attachCamera(cam);
 
			_bmd = new BitmapData(256, 256, false, 0x111111);
			drawVideo();
		}
 
		private function onLoop(e : Event) : void {
			var view : View3D = _view;
 
			view.background = new BitmapTexture(_bmd);
			drawVideo();
			view.render();
		}
 
		private function drawVideo() : void {
			_bmd.draw(_vid, _matrix);
		}
	}
}