Google Maps API for Flash で地図を作る

import com.google.maps.LatLng;
import com.google.maps.Map;
import com.google.maps.MapEvent;
import com.google.maps.MapType;
import com.google.maps.Color;
import com.google.maps.controls.*;
import com.google.maps.styles.*;
 
// start create map
var map:Map = new Map();
// set Google Map API key
map.key = "your API key";
// Map size
map.setSize(new Point(stage.stageWidth, stage.stageHeight));
// set MAP_READY handler
map.addEventListener(MapEvent.MAP_READY, onMapReady);
// set language -- defalut is English
map.language = "ja";
// set Maptype Control
map.addControl(new MapTypeControl());
// set Navigation Control -- zoom / move
map.addControl(new NavigationControl());
// Overview Control style
var cpOption:Object = {
		controlStyle:{
		bevelStyle: BevelStyle.BEVEL_NONE
		,strokeStyle: {color: Color.GRAY10,alpha: 1.0,thickness: 1.0}
		}
		,padding:{x:0,y:0}
		,position: new ControlPosition(ControlPosition.ANCHOR_BOTTOM_RIGHT)
		,size: {x: 100*stage.stageWidth/stage.stageHeight,y: 100}
	};
// set Overview Control
map.addControl(new OverviewMapControl(new OverviewMapControlOptions(cpOption)));
// display
this.addChild(map);
// method of MAP_READY handler
function onMapReady(event:Event):void {
  map.setCenter(new LatLng(33.590832,130.401042), 14, MapType.NORMAL_MAP_TYPE);
}